History Volatility System (Историческая волатильность)

History Volatility – это еще одна из систем, иницилизирующих трейд в случае пробоя уровней текущей рыночной волатильности. Эта система используюет функцию, определяющую историческую волатильность рынка. Система подает сигнал к покупке/продаже, когда на фоне низких текущих уровней волатильности по сравнению с историческими происходит ценовой пробой максимумов/минимумов.

History Volatility Ssytem использует функцию Исторической волатильности (HisVol), которая рассчитывается, как:

INPUTS: LOOKBCK(NumericSimple), ANNUAL(NumericSimple);

Vars: HVol(0), Per(0);

If DataCompression<=2 then Per=1;

{если график daily, intraday или тиковый, то используется переменная Per=1}

If DataCompression=3 then Per=7;

{если график имеет период weekly, то используется переменная Per=7}

HVol=StdDev(LOG(Close/Close[1]),LOOKBCK)*SquareRoot(ANNUAL/Per);

{функция исторической волатильности рассчитывается, как стандартное отклонение за период LOOKBCK натурального логарифма отношения цены закрытия текущего дня к цене закрытия предыдущего дня умноженное на квадратный корень отношения количества дней в году на период графика, Per, т.е. грубо говоря HVol - это нормированный Momentum}

HisVol= HVol*100;

Сама система History Volatility выглядит так:

Inputs: LookBck(6), LookBck2(100), Annual(365);

Vars: HVRatio(0), NR4(False), Inbar(False);

HVRatio = (HisVol(LookBck, Annual) / HisVol(LookBck2, Annual)) * 100;

{рассчитывается переменная HVRatio, как отношение функций исторической волатильности с коротким и длинным периодами, чем большая волатильность наблюдалась на рынке в последнее время, тем больше значение функции HVRatio}

NR4 = Range = Lowest(Range, 4);

{определяем минимальный рэндж (разность между High и Low) за последние 4 дня}

InBar = High < High[1] AND Low > Low[1];

If HVRatio <= 50 AND (NR4 OR InBar) Then Begin

{если текущая волатильность не превышает историческую более, чем на 50%, и разность между максимальным и минимальным значением цен за последние 4 дня достигает своего минимального значения или сегодняшний день – inside day, т.е. максимум дня ниже максимума предыдущего дня, минимум дня выше минимума предыдущего дня, то:}

Buy Next Bar at High + (1 * MinMove Points) Stop;

Sell Next Bar at Low - (1 * MinMove Points) Stop;

End;

Табл. 1

Оптимизация проводилась на внутридневном графике РАО ЕЭС России за период с сентября 1997 г. по октябрь 2000 г..

При анализе системы размер комиссионных брокера и биржи не учитывались, все сделки осуществлялись фиксированной суммой - $10.000.

Рис. 1

На рисунке представлены результаты работы системы Historical Volatility на 15-минутном РАО ЕЭС России.